Bing壁纸

之前用 Windows 自带的批处理做了个提取锁屏壁纸的小功能，原文：《利用批处理文件便捷的提取WIN10锁屏壁纸》，经百度网友"_此方_"提醒，可以在重命名图片文件的时候加上当前日期，所以小改了脚本，如下：

脚本代码

@echo off
title 提取WIN10锁屏必应壁纸
rem 变量 local 为必应壁纸所在的默认文件夹
set local="%USERPROFILE%\AppData\Local\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets\"
rem 变量 target 为提取壁纸后要存储的文件夹，可以自定义，要用绝对路径
set target="E:\Pictures\BingWallPaper\"
rem 变量 count 添加计数器
set /a count=0
@echo 创建存储文件夹
md %target%
@echo 开始清理壁纸目标文件夹
del /q %target%*
@echo 清理完成，开始复制
xcopy /y %local%* %target%
@echo 复制完成，开始更改图片格式
setlocal enabledelayedexpansion
rem 将存储文件夹中的文件命名为“当前日期-序号”的格式
for /f %%s in ('dir /b %target%') do (
    set /a count+=1
    ren %target%%%s %date%-!count!.jpg
    echo 重命名%%s...完成！
)
@echo 完成！
start explorer "%target%"
pause

新增功能

增加了变量的使用，以后要修改更方便了。

不用再手动更改壁纸默认文件夹路径的用户名部分。

不用再手动创建存储文件夹。

脚本中唯一需要自定义的只有存储文件夹的目标路径。

存储文件夹中的图片自动命名为“当前日期-序号”的格式

将以上代码拷贝到一个文本文档，并将.txt后缀更改为.bat就可以使用了。

fix一个小Bug

有些系统使用%date%变量时，系统会输出成YYYY/mm/dd week这样的格式，会导致ren命令出错。

这时需要把%date%输出的字符串进行格式化。

rem %date:~0,4% 表示从第0个字符开始，截取4个字符，包括第0个字符，得到年份
rem %date:~5,2% 表示从第5个字符开始，截取2个字符，包括第5个字符，得到月份
rem %date:~8,2% 表示从第8个字符开始，截取2个字符，包括第8个字符，得到日期
rem 所以把上列代码的ren %target%%%s %date%-!count!.jpg这行修改一下就能避免出错：

ren %target%%%s %date:~0,4%-%date:~5,2%-%date:~8,2%-!count!.jpg

以下是修改后的完整代码：

@echo off
title 提取WIN10锁屏必应壁纸
rem 变量 local 为必应壁纸所在的默认文件夹
set local="%USERPROFILE%\AppData\Local\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets\"
rem 变量 target 为提取壁纸后要存储的文件夹，可以自定义，要用绝对路径
set target="E:\Pictures\BingWallPaper\"
rem 变量 count 添加计数器
set /a count=0
@echo 创建存储文件夹
md %target%
@echo 开始清理壁纸目标文件夹
del /q %target%*
@echo 清理完成，开始复制
xcopy /y %local%* %target%
@echo 复制完成，开始更改图片格式
setlocal enabledelayedexpansion
rem 将存储文件夹中的文件命名为“当前日期-序号”的格式
for /f %%s in ('dir /b %target%') do (
    set /a count+=1
    ren %target%%%s %date:~0,4%-%date:~5,2%-%date:~8,2%-!count!.jpg
    echo 重命名%%s...完成！
)
@echo 完成！
start explorer "%target%"
pause